mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-07-07 11:46:17 +09:00
f62fb99941
A recent gcc added a new unaligned rodata section called '.rodata.str1.1', which needs to be added the the linker script. Instead of just adding this one section, we use a wildcard ".rodata*" to get all rodata linker section gcc has now and might add in the future. However, '*(.rodata*)' by itself will result in sub-optimal section ordering. The sections will be sorted by object file, which causes extra padding between the unaligned rodata.str.1.1 of one object file and the aligned rodata of the next object file. This is easy to fix by using the SORT_BY_ALIGNMENT command. This patch has not be tested one most of the boards modified. Some boards have a linker script that looks something like this: *(.text) . = ALIGN(16); *(.rodata) *(.rodata.str1.4) *(.eh_frame) I change this to: *(.text) . = ALIGN(16); *(.eh_frame) *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) This means the start of rodata will no longer be 16 bytes aligned. However, the boundary between text and rodata/eh_frame is still aligned to 16 bytes, which is what I think the real purpose of the ALIGN call is. Signed-off-by: Trent Piepho <xyzzy@speakeasy.org>
136 lines
3.3 KiB
Plaintext
136 lines
3.3 KiB
Plaintext
/*
|
|
* (C) Copyright 2004, Psyent Corporation <www.psyent.com>
|
|
* Scott McNutt <smcnutt@psyent.com>
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
|
|
OUTPUT_FORMAT("elf32-littlenios2")
|
|
OUTPUT_ARCH(nios2)
|
|
ENTRY(_start)
|
|
|
|
SECTIONS
|
|
{
|
|
.text :
|
|
{
|
|
cpu/nios2/start.o (.text)
|
|
*(.text)
|
|
*(.text.*)
|
|
*(.gnu.linkonce.t*)
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
*(.gnu.linkonce.r*)
|
|
}
|
|
. = ALIGN (4);
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
|
|
/* CMD TABLE - sandwich this in between text and data so
|
|
* the initialization code relocates the command table as
|
|
* well -- admittedly, this is just pure laziness ;-)
|
|
*/
|
|
__u_boot_cmd_start = .;
|
|
.u_boot_cmd :
|
|
{
|
|
*(.u_boot_cmd)
|
|
}
|
|
. = ALIGN(4);
|
|
__u_boot_cmd_end = .;
|
|
|
|
/* INIT DATA sections - "Small" data (see the gcc -G option)
|
|
* is always gp-relative. Here we make all init data sections
|
|
* adjacent to simplify the startup code -- and provide
|
|
* the global pointer for gp-relative access.
|
|
*/
|
|
_data = .;
|
|
.data :
|
|
{
|
|
*(.data)
|
|
*(.data.*)
|
|
*(.gnu.linkonce.d*)
|
|
}
|
|
|
|
. = ALIGN(16);
|
|
_gp = .; /* Global pointer addr */
|
|
PROVIDE (gp = .);
|
|
|
|
.sdata :
|
|
{
|
|
*(.sdata)
|
|
*(.sdata.*)
|
|
*(.gnu.linkonce.s.*)
|
|
}
|
|
. = ALIGN(4);
|
|
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
|
|
/* UNINIT DATA - Small uninitialized data is first so it's
|
|
* adjacent to sdata and can be referenced via gp. The normal
|
|
* bss follows. We keep it adjacent to simplify init code.
|
|
*/
|
|
__bss_start = .;
|
|
.sbss (NOLOAD) :
|
|
{
|
|
*(.sbss)
|
|
*(.sbss.*)
|
|
*(.gnu.linkonce.sb.*)
|
|
*(.scommon)
|
|
}
|
|
. = ALIGN(4);
|
|
.bss (NOLOAD) :
|
|
{
|
|
*(.bss)
|
|
*(.bss.*)
|
|
*(.dynbss)
|
|
*(COMMON)
|
|
*(.scommon)
|
|
}
|
|
. = ALIGN(4);
|
|
_end = .;
|
|
PROVIDE (end = .);
|
|
|
|
/* DEBUG -- symbol table, string table, etc. etc.
|
|
*/
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug 0 : { *(.debug) }
|
|
.line 0 : { *(.line) }
|
|
.debug_srcinfo 0 : { *(.debug_srcinfo) }
|
|
.debug_sfnames 0 : { *(.debug_sfnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_frame 0 : { *(.debug_frame) }
|
|
.debug_str 0 : { *(.debug_str) }
|
|
.debug_loc 0 : { *(.debug_loc) }
|
|
.debug_macinfo 0 : { *(.debug_macinfo) }
|
|
.debug_weaknames 0 : { *(.debug_weaknames) }
|
|
.debug_funcnames 0 : { *(.debug_funcnames) }
|
|
.debug_typenames 0 : { *(.debug_typenames) }
|
|
.debug_varnames 0 : { *(.debug_varnames) }
|
|
}
|