mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-08-20 08:58:52 +09:00
![Tom Rini](/assets/img/avatar_default.png)
When U-Boot started using SPDX tags we were among the early adopters and there weren't a lot of other examples to borrow from. So we picked the area of the file that usually had a full license text and replaced it with an appropriate SPDX-License-Identifier: entry. Since then, the Linux Kernel has adopted SPDX tags and they place it as the very first line in a file (except where shebangs are used, then it's second line) and with slightly different comment styles than us. In part due to community overlap, in part due to better tag visibility and in part for other minor reasons, switch over to that style. This commit changes all instances where we have a single declared license in the tag as both the before and after are identical in tag contents. There's also a few places where I found we did not have a tag and have introduced one. Signed-off-by: Tom Rini <trini@konsulko.com>
61 lines
1.1 KiB
ArmAsm
61 lines
1.1 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* Written by H. Peter Anvin <hpa@zytor.com>
|
|
* Brought in from Linux v4.4 and modified for U-Boot
|
|
* From Linux arch/um/sys-i386/setjmp.S
|
|
*/
|
|
|
|
#define _REGPARM
|
|
|
|
/*
|
|
* The jmp_buf is assumed to contain the following, in order:
|
|
* %ebx
|
|
* %esp
|
|
* %ebp
|
|
* %esi
|
|
* %edi
|
|
* <return address>
|
|
*/
|
|
|
|
.text
|
|
.align 4
|
|
.globl setjmp
|
|
.type setjmp, @function
|
|
setjmp:
|
|
#ifdef _REGPARM
|
|
movl %eax, %edx
|
|
#else
|
|
movl 4(%esp), %edx
|
|
#endif
|
|
popl %ecx /* Return address, and adjust the stack */
|
|
xorl %eax, %eax /* Return value */
|
|
movl %ebx, (%edx)
|
|
movl %esp, 4(%edx) /* Post-return %esp! */
|
|
pushl %ecx /* Make the call/return stack happy */
|
|
movl %ebp, 8(%edx)
|
|
movl %esi, 12(%edx)
|
|
movl %edi, 16(%edx)
|
|
movl %ecx, 20(%edx) /* Return address */
|
|
ret
|
|
|
|
/* Provide function size if needed */
|
|
.size setjmp, .-setjmp
|
|
|
|
.align 4
|
|
.globl longjmp
|
|
.type longjmp, @function
|
|
longjmp:
|
|
#ifdef _REGPARM
|
|
xchgl %eax, %edx
|
|
#else
|
|
movl 4(%esp), %edx /* jmp_ptr address */
|
|
#endif
|
|
movl (%edx), %ebx
|
|
movl 4(%edx), %esp
|
|
movl 8(%edx), %ebp
|
|
movl 12(%edx), %esi
|
|
movl 16(%edx), %edi
|
|
jmp *20(%edx)
|
|
|
|
.size longjmp, .-longjmp
|