mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-08-19 00:18:51 +09:00
![Andre Przywara](/assets/img/avatar_default.png)
The Allwinner A64 SoC starts execution in AArch32 mode, and both the boot ROM and Allwinner's boot0 keep running in this mode. So U-Boot gets entered in 32-bit, although we want it to run in AArch64. By using a "magic" instruction, which happens to be an almost-NOP in AArch64 and a branch in AArch32, we differentiate between being entered in 64-bit or 32-bit mode. If in 64-bit mode, we proceed with the branch to reset, but in 32-bit mode we trigger an RMR write to bring the core into AArch64/EL3 and re-enter U-Boot at CONFIG_SYS_TEXT_BASE. This allows a 64-bit U-Boot to be both entered in 32 and 64-bit mode, so we can use the same start code for the SPL and the U-Boot proper. We use the existing custom header (boot0.h) functionality, but restrict the existing boot0 header reservation to the non-SPL build now. A SPL wouldn't need such header anyway. This allows to have both options defined and lets us use one for the SPL and the other for U-Boot proper. Also add arch/arm/mach-sunxi/rmr_switch.S, which contains the original ARM assembly code and instructions how to re-generate the encoded version. Signed-off-by: Andre Przywara <andre.przywara@arm.com> Acked-by: Maxime Ripard <maxime.ripard@free-electrons.com> Reviewed-by: Jagan Teki <jagan@openedev.com>
42 lines
1.6 KiB
ArmAsm
42 lines
1.6 KiB
ArmAsm
@
|
|
@ ARMv8 RMR reset sequence on Allwinner SoCs.
|
|
@
|
|
@ All 64-bit capable Allwinner SoCs reset in AArch32 (and continue to
|
|
@ exectute the Boot ROM in this state), so we need to switch to AArch64
|
|
@ at some point.
|
|
@ Section G6.2.133 of the ARMv8 ARM describes the Reset Management Register
|
|
@ (RMR), which triggers a warm-reset of a core and can request to switch
|
|
@ into a different execution state (AArch32 or AArch64).
|
|
@ The address at which execution starts after the reset is held in the
|
|
@ RVBAR system register, which is architecturally read-only.
|
|
@ Allwinner provides a writable alias of this register in MMIO space, so
|
|
@ we can easily set the start address of AArch64 code.
|
|
@ This code below switches to AArch64 and starts execution at the specified
|
|
@ start address. It needs to be assembled by an ARM(32) assembler and
|
|
@ the machine code must be inserted as verbatim .word statements into the
|
|
@ beginning of the AArch64 U-Boot code.
|
|
@ To get the encoded bytes, use:
|
|
@ ${CROSS_COMPILE}gcc -c -o rmr_switch.o rmr_switch.S
|
|
@ ${CROSS_COMPILE}objdump -d rmr_switch.o
|
|
@
|
|
@ The resulting words should be inserted into the U-Boot file at
|
|
@ arch/arm/include/asm/arch-sunxi/boot0.h.
|
|
@
|
|
@ This file is not build by the U-Boot build system, but provided only as a
|
|
@ reference and to be able to regenerate a (probably fixed) version of this
|
|
@ code found in encoded form in boot0.h.
|
|
|
|
.text
|
|
|
|
ldr r1, =0x017000a0 @ MMIO mapped RVBAR[0] register
|
|
ldr r0, =0x57aA7add @ start address, to be replaced
|
|
str r0, [r1]
|
|
dsb sy
|
|
isb sy
|
|
mrc 15, 0, r0, cr12, cr0, 2 @ read RMR register
|
|
orr r0, r0, #3 @ request reset in AArch64
|
|
mcr 15, 0, r0, cr12, cr0, 2 @ write RMR register
|
|
isb sy
|
|
1: wfi
|
|
b 1b
|