mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-08-20 17:08:52 +09:00
![Tom Rini](/assets/img/avatar_default.png)
When U-Boot started using SPDX tags we were among the early adopters and there weren't a lot of other examples to borrow from. So we picked the area of the file that usually had a full license text and replaced it with an appropriate SPDX-License-Identifier: entry. Since then, the Linux Kernel has adopted SPDX tags and they place it as the very first line in a file (except where shebangs are used, then it's second line) and with slightly different comment styles than us. In part due to community overlap, in part due to better tag visibility and in part for other minor reasons, switch over to that style. This commit changes all instances where we have a single declared license in the tag as both the before and after are identical in tag contents. There's also a few places where I found we did not have a tag and have introduced one. Signed-off-by: Tom Rini <trini@konsulko.com>
64 lines
1.2 KiB
ArmAsm
64 lines
1.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0+ */
|
|
/*
|
|
* (C) Copyright 2015 Google, Inc
|
|
* Written by Simon Glass <sjg@chromium.org>
|
|
*/
|
|
|
|
#include <asm/global_data.h>
|
|
#include <asm/msr-index.h>
|
|
#include <asm/processor-flags.h>
|
|
|
|
/*
|
|
* rdi - 32-bit code segment selector
|
|
* rsi - target address
|
|
* rdx - table address (0 if none)
|
|
*/
|
|
.code64
|
|
.globl cpu_call32
|
|
cpu_call32:
|
|
cli
|
|
|
|
/* Save table pointer */
|
|
mov %edx, %ebx
|
|
|
|
/*
|
|
* Debugging option, this outputs characters to the console UART
|
|
* mov $0x3f8,%edx
|
|
* mov $'a',%al
|
|
* out %al,(%dx)
|
|
*/
|
|
|
|
pushf
|
|
push %rdi /* 32-bit code segment */
|
|
lea compat(%rip), %rax
|
|
push %rax
|
|
.byte 0x48 /* REX prefix to force 64-bit far return */
|
|
retf
|
|
.code32
|
|
compat:
|
|
/*
|
|
* We are now in compatibility mode with a default operand size of
|
|
* 32 bits. First disable paging.
|
|
*/
|
|
movl %cr0, %eax
|
|
andl $~X86_CR0_PG, %eax
|
|
movl %eax, %cr0
|
|
|
|
/* Invalidate TLB */
|
|
xorl %eax, %eax
|
|
movl %eax, %cr3
|
|
|
|
/* Disable Long mode in EFER (Extended Feature Enable Register) */
|
|
movl $MSR_EFER, %ecx
|
|
rdmsr
|
|
btr $_EFER_LME, %eax
|
|
wrmsr
|
|
|
|
/* Set up table pointer for _x86boot_start */
|
|
mov %ebx, %ecx
|
|
|
|
/* Jump to the required target */
|
|
pushl %edi /* 32-bit code segment */
|
|
pushl %esi /* 32-bit target address */
|
|
retf
|