mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-08-31 22:39:08 +09:00
![Jason Jin](/assets/img/avatar_default.png)
Introduce the --gc-sections for ColdFire platform and clean up the corresponding lds file. Signed-off-by: TsiChung Liew <tsicliew@gmail.com> Signed-off-by: Jason Jin <Jason.jin@freescale.com>
101 lines
2.2 KiB
Plaintext
101 lines
2.2 KiB
Plaintext
/*
|
|
* (C) Copyright 2000
|
|
* Wolfgang Denk, DENX Software Engineering, wd@denx.de.
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
OUTPUT_ARCH(m68k)
|
|
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
.text :
|
|
{
|
|
arch/m68k/cpu/mcf532x/start.o (.text*)
|
|
|
|
. = DEFINED(env_offset) ? env_offset : .;
|
|
common/env_embedded.o (.text*)
|
|
|
|
*(.text*)
|
|
}
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
.rodata :
|
|
{
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
}
|
|
|
|
/* Read-write section, merged into data segment: */
|
|
. = (. + 0x00FF) & 0xFFFFFF00;
|
|
_erotext = .;
|
|
PROVIDE (erotext = .);
|
|
|
|
.reloc :
|
|
{
|
|
__got_start = .;
|
|
KEEP(*(.got))
|
|
__got_end = .;
|
|
_GOT2_TABLE_ = .;
|
|
KEEP(*(.got2))
|
|
_FIXUP_TABLE_ = .;
|
|
KEEP(*(.fixup))
|
|
}
|
|
__got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
|
|
__fixup_entries = (. - _FIXUP_TABLE_)>>2;
|
|
|
|
.data :
|
|
{
|
|
*(.data*)
|
|
*(.sdata*)
|
|
}
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
|
|
. = .;
|
|
__u_boot_cmd_start = .;
|
|
.u_boot_cmd : { *(.u_boot_cmd) }
|
|
__u_boot_cmd_end = .;
|
|
|
|
. = .;
|
|
__start___ex_table = .;
|
|
__ex_table : { *(__ex_table) }
|
|
__stop___ex_table = .;
|
|
|
|
. = ALIGN(256);
|
|
__init_begin = .;
|
|
.text.init : { *(.text.init) }
|
|
.data.init : { *(.data.init) }
|
|
. = ALIGN(256);
|
|
__init_end = .;
|
|
|
|
__bss_start = .;
|
|
.bss (NOLOAD) :
|
|
{
|
|
_sbss = .;
|
|
*(.sbss*)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
_ebss = .;
|
|
}
|
|
__bss_end__ = . ;
|
|
PROVIDE (end = .);
|
|
}
|