mirror of
https://github.com/brain-hackers/u-boot-brain
synced 2024-07-07 11:46:17 +09:00
a14a94469c
Mpq101 is a RapidIO development board in AMC form factor, featuring MPC8548 processor, 512MB of hardwired DDR2 RAM, 128MB of hardwired NAND flash memory, real time clock and additional serial EEPROM on i2c bus (enabled). USB controller is available, but not presently enabled. Additional board information is available at: http://www.mc.com/products/boards/ensemble_mpq101_rapidio_powerquicc_iii.aspx Environment is configured to precede the actual u-boot image so that it's located at the beginning of flash erase block (made necessary by the recent changes to the embedded environment handling). This is achieved by means of custom ld script. Signed-off-by: Alex Dubov <oakad@yahoo.com> Signed-off-by: Kumar Gala <galak@kernel.crashing.org>
133 lines
3.0 KiB
Plaintext
133 lines
3.0 KiB
Plaintext
/*
|
|
* Copyright 2007-2009 Freescale Semiconductor, Inc.
|
|
*
|
|
* See file CREDITS for list of people who contributed to this
|
|
* project.
|
|
*
|
|
* This program is free software; you can redistribute it and/or
|
|
* modify it under the terms of the GNU General Public License as
|
|
* published by the Free Software Foundation; either version 2 of
|
|
* the License, or (at your option) any later version.
|
|
*
|
|
* This program is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU General Public License
|
|
* along with this program; if not, write to the Free Software
|
|
* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
|
|
* MA 02111-1307 USA
|
|
*/
|
|
|
|
#ifndef RESET_VECTOR_ADDRESS
|
|
#define RESET_VECTOR_ADDRESS 0xfffffffc
|
|
#endif
|
|
|
|
#include <config.h>
|
|
|
|
OUTPUT_ARCH(powerpc)
|
|
|
|
PHDRS
|
|
{
|
|
text PT_LOAD;
|
|
bss PT_LOAD;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
. = + SIZEOF_HEADERS;
|
|
.interp : { *(.interp) }
|
|
/* To simplify mass deployment, environment precedes the monitor text in the
|
|
* same flash sector.
|
|
*/
|
|
.ppcenv CONFIG_ENV_ADDR : { common/env_embedded.o (.ppcenv) }
|
|
.text :
|
|
{
|
|
*(.text*)
|
|
} :text
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
.rodata :
|
|
{
|
|
*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
|
|
} :text
|
|
|
|
/* Read-write section, merged into data segment: */
|
|
. = (. + 0x00FF) & 0xFFFFFF00;
|
|
_erotext = .;
|
|
PROVIDE (erotext = .);
|
|
.reloc :
|
|
{
|
|
_GOT2_TABLE_ = .;
|
|
KEEP(*(.got2))
|
|
KEEP(*(.got))
|
|
PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
|
|
_FIXUP_TABLE_ = .;
|
|
KEEP(*(.fixup))
|
|
}
|
|
__got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
|
|
__fixup_entries = (. - _FIXUP_TABLE_) >> 2;
|
|
|
|
.data :
|
|
{
|
|
*(.data*)
|
|
*(.sdata*)
|
|
}
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
|
|
. = .;
|
|
__u_boot_cmd_start = .;
|
|
.u_boot_cmd : { *(.u_boot_cmd) }
|
|
__u_boot_cmd_end = .;
|
|
|
|
. = .;
|
|
__start___ex_table = .;
|
|
__ex_table : { *(__ex_table) }
|
|
__stop___ex_table = .;
|
|
|
|
. = ALIGN(256);
|
|
__init_begin = .;
|
|
.text.init : { *(.text.init) }
|
|
.data.init : { *(.data.init) }
|
|
. = ALIGN(256);
|
|
__init_end = .;
|
|
|
|
.bootpg RESET_VECTOR_ADDRESS - 0xffc :
|
|
{
|
|
arch/powerpc/cpu/mpc85xx/start.o (.bootpg)
|
|
} :text = 0xffff
|
|
|
|
.resetvec RESET_VECTOR_ADDRESS :
|
|
{
|
|
KEEP(*(.resetvec))
|
|
} :text = 0xffff
|
|
|
|
. = RESET_VECTOR_ADDRESS + 0x4;
|
|
|
|
/*
|
|
* Make sure that the bss segment isn't linked at 0x0, otherwise its
|
|
* address won't be updated during relocation fixups. Note that
|
|
* this is a temporary fix. Code to dynamically the fixup the bss
|
|
* location will be added in the future. When the bss relocation
|
|
* fixup code is present this workaround should be removed.
|
|
*/
|
|
#if (RESET_VECTOR_ADDRESS == 0xfffffffc)
|
|
. |= 0x10;
|
|
#endif
|
|
|
|
__bss_start = .;
|
|
.bss (NOLOAD) :
|
|
{
|
|
*(.sbss*)
|
|
*(.bss*)
|
|
*(COMMON)
|
|
} :bss
|
|
|
|
. = ALIGN(4);
|
|
_end = . ;
|
|
PROVIDE (end = .);
|
|
}
|