mirror of
https://github.com/brain-hackers/linux-brain.git
synced 2024-06-09 23:36:23 +09:00
335104082c
commit 78762b0e79bc1dd01347be061abdf505202152c9 upstream. All these are functions which are invoked from elsewhere but they are not typical C functions. So annotate them using the new SYM_CODE_START. All these were not balanced with any END, so mark their ends by SYM_CODE_END, appropriately. Signed-off-by: Jiri Slaby <jslaby@suse.cz> Signed-off-by: Borislav Petkov <bp@suse.de> Reviewed-by: Boris Ostrovsky <boris.ostrovsky@oracle.com> [xen bits] Reviewed-by: Rafael J. Wysocki <rafael.j.wysocki@intel.com> [hibernate] Cc: Andy Lutomirski <luto@kernel.org> Cc: "H. Peter Anvin" <hpa@zytor.com> Cc: Ingo Molnar <mingo@redhat.com> Cc: Josh Poimboeuf <jpoimboe@redhat.com> Cc: Juergen Gross <jgross@suse.com> Cc: Len Brown <len.brown@intel.com> Cc: linux-arch@vger.kernel.org Cc: linux-pm@vger.kernel.org Cc: Pavel Machek <pavel@ucw.cz> Cc: Peter Zijlstra <peterz@infradead.org> Cc: Pingfan Liu <kernelfans@gmail.com> Cc: Stefano Stabellini <sstabellini@kernel.org> Cc: "Steven Rostedt (VMware)" <rostedt@goodmis.org> Cc: Thomas Gleixner <tglx@linutronix.de> Cc: x86-ml <x86@kernel.org> Cc: xen-devel@lists.xenproject.org Link: https://lkml.kernel.org/r/20191011115108.12392-26-jslaby@suse.cz Signed-off-by: Sasha Levin <sashal@kernel.org>
74 lines
1.8 KiB
ArmAsm
74 lines
1.8 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
*
|
|
* Trampoline.S Derived from Setup.S by Linus Torvalds
|
|
*
|
|
* 4 Jan 1997 Michael Chastain: changed to gnu as.
|
|
*
|
|
* This is only used for booting secondary CPUs in SMP machine
|
|
*
|
|
* Entry: CS:IP point to the start of our code, we are
|
|
* in real mode with no stack, but the rest of the
|
|
* trampoline page to make our stack and everything else
|
|
* is a mystery.
|
|
*
|
|
* We jump into arch/x86/kernel/head_32.S.
|
|
*
|
|
* On entry to trampoline_start, the processor is in real mode
|
|
* with 16-bit addressing and 16-bit data. CS has some value
|
|
* and IP is zero. Thus, we load CS to the physical segment
|
|
* of the real mode code before doing anything further.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/segment.h>
|
|
#include <asm/page_types.h>
|
|
#include "realmode.h"
|
|
|
|
.text
|
|
.code16
|
|
|
|
.balign PAGE_SIZE
|
|
SYM_CODE_START(trampoline_start)
|
|
wbinvd # Needed for NUMA-Q should be harmless for others
|
|
|
|
LJMPW_RM(1f)
|
|
1:
|
|
mov %cs, %ax # Code and data in the same place
|
|
mov %ax, %ds
|
|
|
|
cli # We should be safe anyway
|
|
|
|
movl tr_start, %eax # where we need to go
|
|
|
|
/*
|
|
* GDT tables in non default location kernel can be beyond 16MB and
|
|
* lgdt will not be able to load the address as in real mode default
|
|
* operand size is 16bit. Use lgdtl instead to force operand size
|
|
* to 32 bit.
|
|
*/
|
|
lidtl tr_idt # load idt with 0, 0
|
|
lgdtl tr_gdt # load gdt with whatever is appropriate
|
|
|
|
movw $1, %dx # protected mode (PE) bit
|
|
lmsw %dx # into protected mode
|
|
|
|
ljmpl $__BOOT_CS, $pa_startup_32
|
|
SYM_CODE_END(trampoline_start)
|
|
|
|
.section ".text32","ax"
|
|
.code32
|
|
SYM_CODE_START(startup_32) # note: also used from wakeup_asm.S
|
|
jmp *%eax
|
|
SYM_CODE_END(startup_32)
|
|
|
|
.bss
|
|
.balign 8
|
|
GLOBAL(trampoline_header)
|
|
tr_start: .space 4
|
|
tr_gdt_pad: .space 2
|
|
tr_gdt: .space 6
|
|
END(trampoline_header)
|
|
|
|
#include "trampoline_common.S"
|